前言前一篇文章中我们写提到了点击button控件可能会触发pressed,released,clicked信号，这个应用就属于信号与槽。信号和槽作为Qt的和新机制，在Qt编程中有着非常广泛的应用。事实上，我们在Qt开发中，要想妥善的处理各种事件，根本就离不开信号与槽。信号是事件，信号通过信号处理程序来响应。当一个信号被发射时，相应的信号处理程序就会被调用，在处理程序中编写代码来使控件响应事件。 信号处理程序信号处理器先来介绍第一种方法，通过信号处理器。通常是链接QML类型的已知信号，分为两类。一类是由用户输入产生，比如说按键、鼠标等；另一类是由对象的状态或者属性变化产生的，比如说鼠标被按下或释放等。先来通过按键关闭程序来看一下。 Button{
text: "quit"
anchors.centerIn: parent
onClicked: {
Qt.quit()
}
}每当按钮被点击时，onClicked处理程序就会被调用，可以在此程序中设置退出应用闭或者其他的操作。是不是很简单？运行看一下效果。
总结一下信号处理器的用法，当信号被发射时，对象定义就声明一个名为on<Signal>的信号处理程序，其中，<Signal>是信号的名称，首字母必须大写。我们在处理程序中编写想要实现的效果。 属性改变信号处理程序的用法也非常简单，通常以on<Property>Changed的形式写入，<Property>是属性的名称，首字母大写。我们提到的这两种信号处理器都是放在当前元素的内部，如果要处理的信号不是当前元素发出来的呢？这就引出了我们接下来要说的附加信号处理器。 附加信号处理器对象本身或者其基类没有的属性和信号，需要通过外部（附加类型）提供。看个官方文档的例程，运行程序，控制台会输出“哈哈哈”的信息 <AttachingType>.on<Signal>Item{
width: 100
height: 100
focus: true
Keys.enabled: true
Keys.onReturnPressed: console.log("哈哈哈")
}之前提过Item不可见，通过附加类型Keys来访问其附加属性和附加的信号处理程序。enable设置为true，表明启用键盘处理。因为Keys提供了returnPressed信号，所以可以通过onReturnPressed来引用附加信号处理程序。 Connections前面的两种方式都是用on<Signal>的方式，但是当我们遇到下面的情况时：
这个时候，我们就需要使用Connections Rectangle{
id:rect
anchors.fill: parent
color: "red"
Button{
id:button
width: 100
height: 30
text: "改变颜色"
anchors.centerIn: rect
}
Connections{
target: button
onClicked:{
rect.color = "green"
}
}
}定义一个充满窗口的红色矩形，在其中间设置一个按钮，我们想要实现的效果就是按下按钮，矩形的颜色变成绿色。注意Connections的用法，我们只需要将onClicked处理程序放置其中，并制定target就可以了！效果如下：
自定义信号当QML现有的信号无法满足时，我们就需要自定义信号了。通过关键字signal来添加自定义的信号。语法结构为：signal <name>[([<type> <parameter name>[, ...]])]我们还是通过例子来了解自定义信号的使用，还是上一节中定义的矩形,我们在里面定义属性和信号。自定义属性的方法也很简单，语法结构如下： [default] property <propertyType> <propertyName> : <value>Rectangle{
id: rect
anchors.fill: parent
color:"green"
property int clickcount: 0 //自定义点击次数
signal signal1 //自定义无参信号
signal signal2(string str,int value) //定义有参信号
}在Qt c++中通过emit来发射信号，而在QML中直接将声明的信号当做函数来调用就可以触发了。所以我们继续在Rectangle对象中再定义一个按钮button，在其信号处理程序中直接调用定义的信号函数。 Button{
text: "点击我"
anchors.centerIn: rect
onClicked: {
rect.clickcount++
rect.signal2("点击第",rect.clickcount)
if(rect.clickcount%5===0)
{
rect.signal1()
}
}
}每次点击，点击次数都会累加且调用signal2函数，当点击次数增加到5时，同时调用siagnl1函数。既然定义了信号函数，必然会有信号处理函数。我们想要实现的效果是每次点击，都会输出现在点击的是第几次。当点击到第5和5的倍数次时，矩形的颜色随机改变。还是在Rectangle对象中输入以下代码 onSignal1: {
rect.color = Qt.rgba(Math.random(), Math.random(),Math.random(), 1)
}
onSignal2: {
console.log(str,value,"次")
}最后实现效果如下：
信号与槽的连接大多数情况下，通过上面两种方式接收信号就足够啦，然而，要将信号连接至多个方法/信号，信号处理程序根本就无法实现。在QtWidgets中，信号与槽的连接方式使用的是QObject::connect()。相应的，在QtQuick中，signal对象也有一个connect()方法，用于将信号连接到一个或多个方法/信号。当信号连接到方法时，无论信号何时发出，该方法都将被自动调用。有了这种机制，可以通过方法来接收信号，而无需使用信号处理器。也可以通过disconnect()来取消连接。 Rectangle{
id: rect
anchors.fill: parent
//定义信号
signal signal1(string str)
signal signal2(string str)
Row{
id: row
anchors.centerIn: rect
Label{
id:text1
text: "a"
padding: 80
}
Label{
id: text2
text: "b"
padding: 80
}
Label{
id: text3
text: "c"
padding: 80
}
}
Button{
anchors.top: row.bottom
anchors.horizontalCenter: rect.horizontalCenter
text: "变成大写"
onClicked: {
rect.signal1("变为大写了！！！")
}
}
Component.onCompleted: {
//连接到方法
rect.signal1.connect(method1)
rect.signal1.connect(method2)
rect.signal1.connect(method3)
//连接到信号
rect.signal1.connect(rect.signal2)
}
//信号处理程序
onSignal2: {
console.log(str)
}
//定义方法
function method1(){
text1.text = "A"
}
function method2(){
text2.text = "B"
}
function method3(){
text3.text = "C"
}
}我们在Rectangle对象中通过布局管理器定义了三个label和一个按钮。label控件非常简单，它继承于Text，所有的属性都和Text元素一样。当button的click信号被发射时，调用signal1函数，然后在下面将signal1信号连接到signal2信号和方法，这样，新定义的信号被发射，从而执行对应的信号处理函数，同时调用新定义的方法执行程序。运行看一下效果。
总结源码：8.zip |
